xm-common/common/publish.gradle

apply plugin: 'maven-publish'
apply from: 'config.gradle'

task androidJavadocs(type: Javadoc) {
    source = android.sourceSets.main.java.sourceFiles
    ext.androidJar = "${android.sdkDirectory}/platforms/${android.compileSdkVersion}/android.jar"
    classpath += files(ext.androidJar)
}

task androidJavadocsJar(type: Jar) {
    getArchiveClassifier().set("javadoc")
    from androidJavadocs.destinationDir
}

task androidSourcesJar(type: Jar) {
    getArchiveClassifier().set("sources")
    from android.sourceSets.main.java.srcDirs
}

String GROUP_ID = "extra.common"
String ARTIFACT_ID = "core"
String ver = "$ext.atmob_common_version_name"

String publishUrl = !ver.endsWith("-SNAPSHOT") ? "$atmob_maven_url/repository/android-release/"
        : "$atmob_maven_url/repository/android-snapshot/"

afterEvaluate {
    publishing {
        publications {
            // Creates a Maven publication called "release".
            push(MavenPublication) {
                from components.release

                groupId = GROUP_ID
                artifactId = ARTIFACT_ID
                version = ver

                artifact androidSourcesJar
                artifact androidJavadocsJar
            }

        }
        repositories {
            maven {
                name = "nexus"
                allowInsecureProtocol true
                credentials {
                    username = "$atmob_maven_username"
                    password = "$atmob_maven_password"
                }
                url = publishUrl
            }
        }
    }
}