xm-common/room-rx/publish.gradle

apply plugin: 'maven-publish'

task androidJavadocs(type: Javadoc) {
    source = android.sourceSets.main.java.sourceFiles
    ext.androidJar = "${android.sdkDirectory}/platforms/${android.compileSdkVersion}/android.jar"
    classpath += files(ext.androidJar)
}

task androidJavadocsJar(type: Jar) {
    getArchiveClassifier().set("javadoc")
    from androidJavadocs.destinationDir
}

task androidSourcesJar(type: Jar) {
    getArchiveClassifier().set("sources")
    from android.sourceSets.main.java.srcDirs
}


String ver = "2.5.0-SNAPSHOT"

String publishUrl = !ver.endsWith("-SNAPSHOT") ? "$atmob_maven_url/repository/android-release/"
        : "$atmob_maven_url/repository/android-snapshot/"


String GROUP_ID = "extra.room"
String ARTIFACT_ID = "room-rxjava3"


afterEvaluate {
    publishing {
        publications {
            // Creates a Maven publication called "release".
            push(MavenPublication) {
                from components.release

                groupId = GROUP_ID
                artifactId = ARTIFACT_ID
                version = ver

                artifact androidSourcesJar
                artifact androidJavadocsJar
            }

        }
        repositories {
            maven {
                name = "nexus"
                allowInsecureProtocol true
                credentials {
                    username = "$atmob_maven_username"
                    password = "$atmob_maven_password"
                }
                url = publishUrl
            }
        }
    }
}